stop();
//setup image array
burl = "http://www.your-hosted-domain.com/"; //base url
imgs = new Array("img1.jpg", "img2.jpg", "img3.jpg");
//setup some vars
current_img = 0;
last_depth = 0;
//setup some functions
function startShow (slide_delay:Number):Void {
    //attach a image holder mc
    var imc:MovieClip = _root.createEmptyMovieClip("images", 10);
    //show timer
    var t:Number = setInterval(updateShow, slide_delay);
    //init first img
    updateShow();
}

function updateShow ():Void {
    //build path
    var image_path:String = burl + imgs[current_img];
    //get a depth
    last_depth = _root.images.getNextHighestDepth(); //depth
    //load it
    var image_holder:MovieClip = _root.images.createEmptyMovieClip("holder"+last_depth, last_depth);
    loadImage(image_path, image_holder);
    //update counter
    current_img++;
    //update counter loop
    if (current_img == imgs.length) {
        current_img = 0; //reset for loop
    }
}

function unloadLastImage () {
    var imc:MovieClip = _root.images;
    var last_image:MovieClip = imc["holder"+(last_depth-1)];
    
    if (last_image != undefined) {
        last_image.removeMovieClip();
    }
}

function loadImage (image_path, load_clip) {
    var ls:Object = new Object();
    ls.onLoadInit = function(target_mc:MovieClip) {
        _root.unloadLastImage();
    };
    
    var mcl:MovieClipLoader = new MovieClipLoader();
    mcl.addListener(ls);
    mcl.loadClip(image_path, load_clip);
}

//start show with 5 second delay between images
startShow(5000);